Еще один способ получения дампа реестра запрещенных сайтов Роскомнадзора.

Согласно памятке оператора необходимо сгенерировать файл в формате xml следующей структуры (файл должен быть в кодировке win-1251):

<?xml version="1.0" encoding="windows-1251"?>
<request>
<requestTime>2014-01-01T01:01:01.000+04:00</requestTime>
<operatorName>Наименование оператора</operatorName>
<inn>1234567890</inn>
<ogrn>1234567890123</ogrn>
<email>[email protected]</email>
</request>

Для создания электронной подписи будем использовать утилиту csptest.exe, входящую в состав дистрибутива КриптоПро 3.6 CSP

Далее приведен код bat скрипта

@echo off

rem ВАЖНО! Кодировка .cmd файла должна быть cp1251 !
rem Должно быть установлено программное обеспечение КриптоПро 3.6

rem Имя файла с запросом
set myreq=req.xml
rem Имя файла подписи
set mysig=req.xml.sig

rem Реквизиты компании
rem Название
set myopname=Наименование компании
rem ИИН
set myinn=0000000000
rem ОГРН
set myogrn=0000000000000
rem email для обратной связи
set [email protected]

rem email, который указывался при создании ЭЦП
set [email protected]

rem Преобразование формата даты 01.02.2003 -> 2003-02-01
for /f "tokens=1-3 delims=." %%a in ("%DATE%") do (set mydate=%%c-%%b-%%a)
rem Преобразование формата времени 01:02:03,004 -> 01:02
for /f "tokens=1-2 delims=:" %%a in ("%TIME%") do (set mytime=%%a:%%b)
set h=%TIME:~0,2%
set m=%TIME:~3,2%
set s=%TIME:~6,2%
set ms=%TIME:~9,3%
set curtime=%h%:%m%:%s%:%ms%

rem Генерация файла запроса
echo ^<?xml version="1.0" encoding="windows-1251"?^> > %myreq%
echo ^<request^> >> %myreq%
echo ^<requestTime^>%mydate%T%curtime%0+04:00^</requestTime^> >> %myreq%
echo ^<operatorName^>%myopname%^</operatorName^> >> %myreq%
echo ^<inn^>%myinn%^</inn^> >> %myreq%
echo ^<ogrn^>%myogrn%^</ogrn^> >> %myreq%
echo ^<email^>%myemail%^</email^> >> %myreq%
echo ^</request^> >> %myreq%

rem Генерация подписи
rem Указан путь до папки с исполняемыми файлами Crypto Pro
"C:\...\csptest.exe" -sfsign -sign -detached -add -in %myreq% -out %mysig% -my %mysigemail%

pause

В результате должны получиться файл запроса reg.xml и reg.xml.sig, содержащий электронную подпись. Результат подставляем на странице ручной выгрузки и получаем дамп базы.